Win7電腦怎樣備份系統服務
Win7電腦怎樣備份系統服務
系統服務一般在后臺運行。與用戶運行的程序相比，服務不會出現程序窗口或對話框，那么Win7電腦怎樣備份系統服務呢?下文學習啦小編就分享了Win7電腦備份系統服務的方法，希望對大家有所幫助。
Win7電腦備份系統服務方法
首先，我們啟動記事本，將批處理命令寫入記事本后，保存為saveservice.cmd
TITLE Windows 7服務備份工具
@echo off
@echo ========================================================================
@echo Windows 7服務備份工具 (C) 2011
@echo ========================================================================
@echo.
@echo 該工具能夠自動備份Windows 7的服務狀態，以方便日后進行還原!
@echo.
pause
REM 獲取當前日期和時間
for /f "tokens=1, 2, 3, 4 delims=-/. " %%j in ('Date /T') do set FILENAME=恢復服務_%%j_%%k_%%l_%%m
for /f "tokens=1, 2 delims=: " %%j in ('TIME /T') do set FILENAME=%FILENAME%_%%j_%%k.cmd
REM 獲取所有服務名稱
sc query type= service state= all| findstr /r /C:"SERVICE_NAME:" >tmpsrv.txt
echo 正在保存服務狀態至 %FILENAME% 文件，請稍候……
REM 將當前服務狀態保存至批處理文件
echo @echo 服務狀態保存于%TIME% %DATE% >"%FILENAME%"
echo @pause >>"%FILENAME%"
for /f "tokens=2 delims=:" %%j in (tmpsrv.txt) do @( sc qc %%j |findstr START_TYPE >tmpstype.txt && for /f "tokens=4 delims=:_ " %%s in (tmpstype.txt) do @echo sc config %%j start= %%s >>"%FILENAME%")
echo @pause >>"%FILENAME%"
del tmpsrv.txt
del tmpstype.txt
echo 服務狀態已經保存至%FILENAME%文件中了，您可以隨時運行它來恢復服務。
pause
之后，我們運行它，會
提示“該工具能夠自動備份Windows 7的服務狀態，以方便日后進行還原!”，按任意鍵繼續，按下任意鍵將會提示“正在保存服務狀態至恢復服務.cmd文件，請稍候……”
完成后會提示我們“服務狀態已經保存至恢復服務.cmd文件中了，您可以隨時運行它來恢復服務。”，按任意鍵即退出。同時，會生成一個恢復服務.cmd文件，雙擊它，可以看到@echo 服務狀態保存的注釋信息。
小提示：
上面的批處理命令代碼可直接復制粘貼到記事本中即可，還可以自行修改提示語言信息。
Win7電腦怎樣備份系統服務相關文章：